A Paraboloid Property

Math 282 Computational Geometry

(Based on code from Joseph O’Rourke.)

Draw a paraboloid and a shifted tangent plane

First, we draw a paraboloid.

domain=8; (* controls how much of the xy-plane to draw *)
paraboloid=Plot3D[x^2 + y^2, {x,-domain,domain},{y,-domain,domain}, PlotStyle->Directive[Opacity[0.5]],BoxRatios->{1,1,2}]

The point (a, b, (a^2)+(b^2)) lies on the paraboloid.

a=3;b=2;
pt={a,b,a^2+b^2};

The tangent plane at this point is given by z=2a x +2 b y -(a^2)-(b^2). We will shift this plane upwards by (r^2), where r is a parameter.

r=4;
plane=Plot3D[2 a x + 2 b y - (a^2 + b^2 )+r^2, {x,-domain,domain},{y,-domain,domain}, PlotStyle->Directive[Opacity[0.5],Green]]

Now draw the paraboloid and tangent plane together.

Show[paraboloid,plane]

What do you notice about the intersection of the paraboloid and the plane?

Now draw a cylinder

Now we will plot the point (a, b, (a^2)+(b^2)) on the paraboloid and its projection (a,b,0) onto the xy-plane. We will also draw a cylinder of radius r whose central axis goes through these two points.

pt2={a,b,0};
cylinder=Graphics3D[{Point[{pt,pt2}],Line[{pt,pt2}],Opacity[0.5],Cylinder[{pt2,{a,b, 2(a^2+b^2+r^2)}},r]},ImageSize->Small]

Plot everything together:

Show[paraboloid,plane,cylinder]

Rotate the graph and observe that the intersection of the paraboloid and plane, when projected to the xy-plane, is a circle.

Dynamic Exploration

We will create a module that draws the 3D graph for a user-defined value of r. This relies on some data objects from the code above, but it redraws plane and cylinder for each value of r.

paraboloidExploration[r_]:=Module[{plane,cylinder,graph},
plane=Plot3D[2 a x + 2 b y - (a^2 + b^2 )+r^2, {x,-domain,domain},{y,-domain,domain}, PlotStyle->Directive[Opacity[0.5],Green]];
cylinder=Graphics3D[{{Red,Point[{pt,pt2}],Line[{pt,pt2}]},Opacity[0.5],Cylinder[{pt2,{a,b,2 (a^2+b^2+r^2)}},r]}];
graph=Show[paraboloid,plane,cylinder]
]

Now we will use the Manipulate command to produce the dynamic exploration. Adjust the value of r and rotate the graph to see that the intersection of the paraboloid and plane is always an ellipse, which projects to the xy-plane as a circle.

Manipulate[paraboloidExploration[r],{r,0,10}]