Histograms of averages of iid random variables:

Uniform random variables

k=5;
averages=Table[ Mean[ RandomVariate[UniformDistribution[{0,1}],k] ], 10000];
hPlot=Histogram[averages,{0,1,0.04},"PDF"]

The Unif[0, 1] distribution has mean (1/2) and standard deviation (1/(Sqrt[12])).

mean=0.5;
sd=1/(Sqrt[12]);

Let's plot the previous histogram  along with the normal distribution that it approximates.

Show[hPlot,Plot[PDF[NormalDistribution[mean, sd/Sqrt[k]],x],{x,0,1},PlotRange->All]]

Hypergeometric random variables

k=40;
averages=Table[ Mean[ RandomVariate[HypergeometricDistribution[8,20,50],k] ], 10000];
hPlot=Histogram[averages,{2,5,0.1},"PDF"]

Get the mean and standard deviation of this hypergeometric distribution:

mean = Mean[HypergeometricDistribution[8,20,50]]

sd=StandardDeviation[HypergeometricDistribution[8,20,50]]

Show[hPlot,Plot[PDF[NormalDistribution[mean, sd/Sqrt[k]],x],{x,2,5},PlotRange->All]]

pdf of sum of iid Unif[0,1] random variables

One Unif[0,1] random variable:

f[x_]=PDF[UniformDistribution[],x]

Plot[f[x],{x,-1,2}]

Sum of two Unif[0,1] random variables:

f2[x_]=Convolve[f[t],f[t],t,x]

Plot[f2[x],{x,-1,3}]

Sum of three Unif[0,1] random variables:

f3[x_]=Convolve[f[t],f2[t],t,x]

σ=1/(Sqrt[12])
Plot[{f3[x],PDF[NormalDistribution[3/2,σ Sqrt[3]],x]},{x,-1,4}]

Sum of four Unif[0,1] random variables:

f4[x_]=Convolve[f[t],f3[t],t,x]

Plot[{f4[x],PDF[NormalDistribution[4/2,σ Sqrt[4]],x]},{x,-1,5}]

Sum of eight Unif[0,1] random variables:

f8[x_]=Convolve[f4[t],f4[t],t,x]

Plot[{f8[x],PDF[NormalDistribution[8/2,σ Sqrt[8]],x]},{x,-1,9}]

Probability calculation for the problem about tomatoes:

Probability[380<T<410,T\[Distributed]NormalDistribution[400,3Sqrt[40]]]//N