Exploring the Lucas Numbers

Math 242 Modern Computational Mathematics

Computing generalized Fibonacci (or “gibonacci”) sequences

We will modify our fibonacciList module so that it computes recursive sequences with any starting values that we specify. Specifically, we will compute generalized Fibonacci (or “gibonacci”) sequences defined as follows:

(Subscript[G, 0])=a, (Subscript[G, 1])=b, and (Subscript[G, n])=(Subscript[G, n-2])+(Subscript[G, n-1]) for n>1.

For example, if we set a=0 and b=1, then we get the Fibonacci sequence. If we set a=2 and b=1, then we get the Lucas numbers.

gibonacciList[a_,b_,n_]:=Module[{gibList=Table[0,n+1]},
(* set the initial values (Subscript[G, 0]) and (Subscript[G, 1]) *)
gibList[[1]]=a;
gibList[[2]]=b;

(* compute (Subscript[G, 2]) through (Subscript[G, n]) and store them in the list *)
Do[
gibList[[i]]=gibList[[i-1]]+gibList[[i-2]]
,{i,3,n+1}];

(* return the list *)
gibList
]

Make sure it works:

gibonacciList[2,1,10]

The Lucas Numbers

Since we will explore the Lucas numbers today, let’s create a big list of Lucas numbers:

lucList=gibonacciList[2,1,10000];

Next we create a little function l to adjust the indexing to match the usual mathematical notation. (That is, (Subscript[L, 0])=2, (Subscript[L, 1])=1, etc.)

l[n_]:=lucList[[n+1]]

1. Ratios of Lucas numbers

(a) Examine the ratios ((Subscript[L, n+1])/(Subscript[L, n])) for various n. Do these ratios converge to some number as n increases? Formulate a conjecture supported by your computational evidence.

N[Table[l[n+1]/l[n],{n,1,20}]]

N[(1+(Sqrt[5]))/2]

Conjecture: The Lucas numbers satisfy  (lim_(n->∞))((Subscript[L, n+1])/(Subscript[L, n]))=((1+(Sqrt[5]))/2).

(b) Examine the ratios ((Subscript[L, n+m])/(Subscript[L, n])) for various n and m. Formulate a conjecture about (lim_(n->∞))((Subscript[L, n+m])/(Subscript[L, n])) for m∈{1,2,3,...} supported by your computational evidence.

N[Table[l[n+2]/l[n],{n,1,20}]]

N[((((1+(Sqrt[5]))/2))^2)]

N[Table[l[n+3]/l[n],{n,1,20}]]

N[((((1+(Sqrt[5]))/2))^3)]

Conjecture: The Lucas numbers satisfy  (lim_(n->∞))((Subscript[L, n+m])/(Subscript[L, n]))=(((((1+(Sqrt[5]))/2)))^m) for nonnegative integers m.

2. Is there an analog of Cassini’s identity for the Lucas numbers?

Compute (Subscript[L, n+1])(Subscript[L, n-1])-(Subscript[L, n]^2) for various positive integers n. Formulate a conjecture. How does your conjecture compare to Cassini’s identity for the Fibonacci numbers?

Table[l[n+1]l[n-1]-((l[n])^2),{n,1,10}]

Conjecture: The Lucas numbers satisfy (Subscript[L, n+1])(Subscript[L, n-1])-(Subscript[L, n]^2)=(((-1))^(n+1))5 for positive integers n.

3. Are there polynomial identities involving the Lucas numbers?

findLucasCoefficients[q_]:=Module[{nvals,matrix, vector,sol},
(* set up the nvals *)
nvals=Range[2,2q+2,2];
Print["nvals:",nvals];

(* set up the matrix *)
matrix=Table[l[n]^i,{n,nvals},{i,q,0,-1}];
Print["matrix:",MatrixForm[matrix]];

(* set up the vector *)
vector=Table[l[q*n],{n,nvals}];
Print["vector:",vector];

(* solve the system *)
sol=LinearSolve[matrix,vector];
Print["solution:",sol];

(* return the solution *)
sol
]

(a) Search for an identity of the form (Subscript[L, 2n])=a (Subscript[L, n]^2) +b (Subscript[L, n])+c for some coefficients a,b,c and positive integers n. Formulate a conjecture supported by your computational evidence.

findLucasCoefficients[2]

It looks like the identity is (Subscript[L, 2n])= (Subscript[L, n]^2) -2 for even n. Could it be (Subscript[L, 2n])= (Subscript[L, n]^2) +(((-1))^(n+1))2 for nonnegative n?

TableForm[Table[{n,l[2n],((l[n])^2)+(((-1))^(n+1))2},{n,1,10}],TableHeadings->{None,{"n","(Subscript[L, 2  n])","(Subscript[L, n]^2) +(-1)^(n + 1)2"}}]

(b) Search for an identity of the form (Subscript[L, 3n])=a (Subscript[L, n]^3) +b (Subscript[L, n]^2)+c (Subscript[L, n])+d for some coefficients a,b,c,d and positive integers n. Formulate a conjecture supported by your computational evidence.

findLucasCoefficients[3]

Maybe the identity is (Subscript[L, 3n])= (Subscript[L, n]^3) +(((-1))^(n+1))3(Subscript[L, n]) for nonnegative n?

TableForm[Table[{n,l[3n],((l[n])^3)+(((-1))^(n+1))3l[n]},{n,1,10}],TableHeadings->{None,{"n","(Subscript[L, 3  n])","(Subscript[L, n]^3) +(-1)^(n + 1)3(Subscript[L, n])"}}]

(c) Extend your results from parts (a) and (b). What is the most general statement that you can make about polynomial identities involving Lucas numbers?

findLucasCoefficients[4]

TableForm[Table[{n,l[4n],((l[n])^4)+(((-1))^(n+1))4((l[n])^2)+2},{n,1,10}],TableHeadings->{None,{"n","(Subscript[L, 4  n])","(Subscript[L, n]^4) +(-1)^(n + 1)4(Subscript[L, n]^2) + 2"}}]

findLucasCoefficients[5]

Maybe the identity is (Subscript[L, 5n])= (Subscript[L, n]^5)+(((-1))^(n+1))5(Subscript[L, n]^3) +5(Subscript[L, n]) for nonnegative n?

TableForm[Table[{n,l[5n],((l[n])^5)+(((-1))^(n+1))5((l[n])^3)+5l[n]},{n,1,10}],TableHeadings->{None,{"n","(Subscript[L, 5  n])","(Subscript[L, n]^5) +(-1)^(n + 1)5(Subscript[L, n]^3) + 5(Subscript[L, n])"}}]